學習目標

1、知道單片機的特點和結(jié)構(gòu)。

2、閱讀MCS-51角針腳，掌握其工作原理。

3、了解基本單片機指令，并根據(jù)需要填寫。

4、電子密碼鎖元素特性。

5、了解電子密碼鎖電路圖。

6、了解電子密碼鎖安裝示意圖。

7、了解電子密碼鎖程序。

8、線路安裝、調(diào)試、維護電子密碼鎖。

學習內(nèi)容：

1、單片機的特點和結(jié)構(gòu)。

2、閱讀MCS-51角針腳，掌握其工作原理。

3、了解閱讀命令的結(jié)構(gòu)、類型和書寫。

4、電子鎖電子元件特性。

5、電子鎖的工作原理、特點、類型。

6、電子鎖電子元件測試。

7、電子鎖程序設計。

本學習情況學：44小時

本課題的教育階段可分為：

1、發(fā)出任務書

2、學習過程。

3、開機問題。

4、相關(guān)表格

5、自考題(評價標準、試題)

任務書

隨著生活水平的提高，人們對自己所處環(huán)境安全的要求越來越高。該設計主要基于單片機智能鎖軟硬件設計與實現(xiàn)方法。該電路設計具有按鍵有效提示、輸入錯誤提示、解鎖級別控制、報警電路控制、密碼修改等多種功能?！叭绻恍⌒男孤?，可以隨時修改密碼?！?位密碼共1萬個重復組合，機密性高，靈活性高，特別適合家庭、辦公室和辦公室。

通過這個課題的學習，你可以獨立完成密碼鎖的組裝，并進行那種類型的密碼鎖維修。下圖是密碼鎖電路圖。

圖1電子密碼鎖電路圖

圖2實物圖

設計整個方案

設計創(chuàng)意

總共安裝了9個用戶輸入密鑰，其中4個是有效的密碼按鈕，其馀的是干擾按鈕。按下干擾鍵后，鍵盤輸入電路自動歸零，最初輸入的密碼無效，必須重新輸入。如果用戶輸入密碼超過40秒(一般用戶不超過40秒，用戶不方便的話可以修改)，電路會發(fā)出80秒的警告，如果電路連續(xù)三次警告，電路會鎖定鍵盤5分鐘，防止他人非法操作。

以AT89S51為核心的單片機控制方案。利用單片機靈活的編程設計和豐富的IO端口，以及其控制的準確性，不僅可以實現(xiàn)基本的代碼鎖定功能，還可以添加前存儲、聲光提示，甚至遙控器控制功能。其原理如圖2-2所示。

圖2-2單片機控制程序

打開鎖

通過單片機傳送到解鎖執(zhí)行機構(gòu)，電路驅(qū)動電磁鎖嚙合，達到解鎖目的。其原理如圖2-3所示。

圖2-3代碼解鎖機制示意圖

用戶正確輸入密碼后，單片機輸出開門信號，發(fā)送到解鎖驅(qū)動電路，然后驅(qū)動電磁鎖，達到開門的目的。實際電路如圖2-4所示。

電路包括兩個階段：驅(qū)動和解鎖。由D5、R1、T10組成的驅(qū)動電路，其中T10可以選擇常規(guī)低功耗三極管，例如9014、9018。D5是解鎖指示燈。由D6、C24、T11組成，解除鎖定。其中，D6、C24旨在消除電磁鎖定可能產(chǎn)生的反向高壓和可能產(chǎn)生的電磁干擾。T11可以選擇中等功率的三極管，比如8050，電磁鎖的選擇取決于情況，但吸力要充足，稍有空閑。

注：設計中暫時使用發(fā)光二極管代替電磁鎖，發(fā)光管打開后意味著解鎖。關(guān)閉，意味著鎖沒有打開。

"549" height="251"/>

圖2－4密碼鎖開鎖機構(gòu)電路圖

按鍵電路設計

由于設計要求使用矩陣鍵盤，所以本設計就采用行列式鍵盤，同時也能減少鍵盤與單片機接口時所占用的I/O線的數(shù)目，在按鍵比較多的時候，通常采用這樣方法。其原理如圖2－5所示。

圖2－5 行列式鍵盤原理電路圖

每一條水平（行線）與垂直線（列線）的交叉處不相通，而是通過一個按鍵來連通，利用這種行列式矩陣結(jié)構(gòu)只需要N條行線和M條列線，即可組成具有N×M個按鍵的鍵盤。

首先辨別鍵盤中有無鍵按下，有單片機I/O口向鍵盤送全掃描字，然后讀入行線狀態(tài)來判斷。方法是：向行線輸出全掃描字00H，把全部列線置為低電平，然后將列線的電平狀態(tài)讀入累加器A中。如果有按鍵按下，總會有一根行線電平被拉至低電平從而使行線不全為1。判斷鍵盤中哪一個鍵被按下使通過將列線逐列置低電平后，檢查行輸入狀態(tài)來實現(xiàn)的。方法是：依次給列線送低電平，然后查所有行線狀態(tài)，如果全為1，則所按下的鍵不在此列；如果不全為1，則所按下的鍵必在此列，而且是在與零電平行線相交的交點上的那個鍵。

按鍵的操作面板如圖2－6所示。共計數(shù)字鍵10個，功能鍵2個。

圖2－6按鍵操作面板示意圖

10個數(shù)字鍵用來輸入密碼，另外2個功能鍵分別是：開鎖和上鎖。上鎖和開鎖的過程在1-2中已經(jīng)詳細介紹,在此不再說。。

面板上還有一個蜂鳴器，其中一個功能是用來指示操作的按鍵是否在成功的按下；另外一個功能是當用戶輸入密碼錯誤的次數(shù)超過了3次，鳴笛以示報警。

顯示電路設計

本系統(tǒng)設計的顯示電路為了節(jié)約單片機的接口資源而采用串行顯示的方式，只使用單片機的兩個串行口，就可以完成單片機的顯示功能，顯示電路的電路原理圖如圖2－7所示。

電路設定：當程序檢測在5分鐘內(nèi)沒有按鍵操作的時候，就關(guān)閉顯示。這個功能使用程序來實現(xiàn)的，一旦沒有按鍵動作就啟動一個定時器，檢測在5分鐘內(nèi)沒有按鍵動作的時候，啟動一個程序，關(guān)閉顯示，這樣可以達到節(jié)省電能的目的。

從單片機串口輸出的信號先送到左邊的移位寄存器（74HC164）,由于移位脈沖的作用，使數(shù)據(jù)向右移，達到顯示的目的。移位寄存器74HC164還兼作數(shù)碼管的驅(qū)動，插頭1（header1）接電源，插頭2（header2）接數(shù)據(jù)和脈沖輸出端。電路中的三個整流管D1~D3的作用是降低數(shù)碼管的工作電壓，增加其使用壽命。

圖2－7顯示器原理圖

程序

程序：

;=====================定義參數(shù)=============================

LED_ON BIT 00H;數(shù)碼管亮暗標志（1為亮，0為暗）

KEYCARD BIT 01H;按鍵標志

PWD_RIGHT BIT 02H;密碼是否正確（1 為正確，0為錯誤）

KEY_LOCK BIT 03H;鍵盤鎖定（1為鎖，0為開）

SOND BIT P1.4;蜂鳴器

GREEN BIT P1.5;綠燈

RED BIT P1.6;紅燈

LED1 EQU 50H;數(shù)碼管自動變暗時間數(shù)1

KEYS EQU 53H;按鍵鍵值

KEY1 EQU 54H;按鍵行值

PWD1 EQU 56H;存密碼1

PWD2 EQU 57H;存密碼2

PWD3 EQU 58H;存密碼3

PWD4 EQU 59H;存密碼4

SHOW1 EQU 5AH;顯示1

SHOW2 EQU 5BH;顯示2

SHOW3 EQU 5CH;顯示3

SHOW4 EQU 5DH;顯示4

SHOW0 EQU 5EH;臨時用

;====================程序開始==============================

ORG 0000H

AJMP INIT

;=====================初始化===============================

ORG 0030H

INIT:

MOV P0, #40H

MOV P2, #0FH

MOV P3, #00H

MOV LED1, #3FH

MOV KEYS, #00H

MOV KEY1, #00H

MOV SHOW0,#00H

MOV SHOW1,#00H

MOV SHOW2,#10H

MOV SHOW3,#20H

MOV SHOW4,#30H

LCALL PWD_INIT

SETB LED_ON

CLR PWD_RIGHT

SETB SOND

SETB RED

SETB GREEN

CLR KEY_LOCK

CLR KEYCARD

AJMP MAIN

;===========================================================主程序======================================================

MAIN:

MOV P2,#0FH

MOV P3,#00H

LCALL KEY_FIRST ;調(diào)用鍵盤程序

JNB KEYCARD,MAIN ;KEYCARD=0時，無鍵按下跳回MAIN

LCALL KEY_MAIN ;KEYCARD=0時，調(diào)用鍵盤處理程序

JNB KEYCARD,MAIN

LJMP MKEY_FUNCTION ;跳到主程序鍵盤各按鍵處理程序

;============================================================END========================================================

;=====================檢測按鍵第一次按下========================

KEY_FIRST:

JNB LED_ON,KEY_LOOP

MOV A, P2 ;數(shù)碼管亮時掃描

ANL A, #0FH ;屏敝掉高4位

CJNE A, #0FH,KEY_SECOND ;判斷是否有鍵按下

CLR KEYCARD ;無鍵則KEYCARD置0

LCALL LED_DISPLAY ;調(diào)用顯示子程序

DJNZ LED1, ESC

CLR LED_ON

MOV LED1, #03FH

ESC:

RET

KEY_LOOP: ;數(shù)碼管暗時掃描

MOV A, P2

ANL A, #0FH

CJNE A, #0FH,KEY_SECOND

CLR KEYCARD

RET

;=======================檢測按鍵第二次按下=================

KEY_SECOND:

LCALL BEEP1 ;按鍵響聲

JNB LED_ON,KEY_EXIT1 ;如果LED是暗的，則置LED_ON為1

MOV LED1, #03FH

LCALL DELAY10MS ;去抖，延時10ms

MOV A, P2 ;重新掃描鍵盤

ANL A, #0FH

CJNE A, #0FH,KEY_EN ;有鍵按下，則置KEYCARD為1

CLR KEYCARD ;無鍵按下，則置KEYCARD為0

RET

KEY_EXIT1:

LCALL KEY_RELEASE

SETB LED_ON

RET

KEY_EN:

SETB KEYCARD ;置KEYCARD為1

RET

;===============================================KEY_MAIN=================================================

KEY_MAIN:

MOV R3,#0EH

MOV R4,#04H ;循環(huán)次數(shù)

KEY_ROW:

MOV P3,R3

MOV A,P2

ANL A,#0FH

MOV KEY1,R3 ;將行信息存到KEY1中

CJNE A,#0FH,KEY_WORD ;是該行則跳到鍵值計算程序

MOV A,R3

SETB C

RLC A ;帶進位循環(huán)左移

ANL A,#0FH

MOV R3,A

DJNZ R4, KEY_ROW

CLR KEYCARD

RET

;================鍵值計算========================

KEY_WORD:

SWAP A

ORL A,KEY1 ;列＋行＝鍵值

MOV KEYS,A ;鍵值存到KEYS中

RET

;==================================主程序各按鍵功能=======================================

MKEY_FUNCTION:

MOV KEYS,A ;鍵值賦給A

MK0:

CJNE A,#0EEH,MK1

CLR KEYCARD

MOV SHOW1,#0BH

MOV SHOW2,#1BH

MOV SHOW3,#2BH

MOV SHOW4,#3BH

LCALL KEY_RELEASE ;按鍵松開程序

MOV R5,#05H

MOV R6,#03H

CLR KEY_LOCK

LOGIN_MAIN: ;輸入密碼主程序

MOV P2, #0FH

MOV P3, #00H

LCALL KEY_FIRST ;調(diào)用鍵盤掃描程序

JNB KEYCARD,LOGIN_MAIN

LCALL KEY_MAIN ;調(diào)用鍵盤處理程序

LJMP LKEY_FUNCTION ;跳到輸密碼時各鍵功能處理程序

MK1:

LCALL KEY_RELEASE

LJMP MAIN

;========＝＝＝＝＝＝＝＝=========================END====================================

;==========================出廠密碼============================

PWD_INIT:

MOV PWD1, #01H

MOV PWD2, #02H

MOV PWD3, #03H

MOV PWD4, #04H

RET

;======================================輸入密碼時各按鍵功能====================================

LKEY_FUNCTION:

MOV A,KEYS

;=================無效鍵============================

LK0:

CJNE A,#0EEH,LK1

LCALL LAMP_RED ;閃紅燈

LCALL KEY_RELEASE

LJMP LOGIN_MAIN ;返回輸入密碼主程序

LK1:

CJNE A,#0EDH,LK2

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP LOGIN_MAIN

LK2:

CJNE A,#0EBH,LK3

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP LOGIN_MAIN

;=================退出鍵==================

LK3:

CJNE A,#0E7H,LK4

MOV SHOW1,#00H

MOV SHOW2,#10H

MOV SHOW3,#20H

MOV SHOW4,#30H

CLR KEY_LOCK

LJMP MAIN ;返回主程序

;===============清除鍵=========================

LK4:

CJNE A,#07BH,LK5

MOV SHOW1,#0BH

MOV SHOW2,#1BH

MOV SHOW3,#2BH

MOV SHOW4,#3BH

MOV R5, #05H

LCALL KEY_RELEASE

LJMP LOGIN_MAIN

;================確定鍵=========================

LK5:

CJNE A,#077H,LK6

LCALL PWD_COMPARE ;調(diào)用密碼檢測子程序

LCALL KEY_RELEASE

JB PWD_RIGHT,SYS_LOGIN ;PWD_RIGHT為1時表示密碼正確，跳到SYS_LOGIN

DJNZ R6,LK5_EXIT ;否則將輸入次數(shù)R6減1

INC R6 ;若輸入次數(shù)已經(jīng)是3次了，就保持R6為1

SETB KEY_LOCK ;置KEY_LOCK為1

LK5_EXIT:

MOV SHOW1,#0BH

MOV SHOW2,#1BH

MOV SHOW3,#2BH

MOV SHOW4,#3BH

MOV R5, #05H

LK5_ESC:

LCALL KEY_RELEASE

LJMP LOGIN_MAIN ;返回輸入密碼主程序

;=============0-9數(shù)字鍵========================

LK6:

MOV R0,#00H

JB KEY_LOCK,LK6_EXIT ;置KEY_LOCK為1時鎖定數(shù)字鍵

DJNZ R5,LKEY_NUM ;輸入個數(shù)滿4個則鎖定數(shù)字鍵，否則R5減1

INC R5 ;若輸入個數(shù)已經(jīng)是4個了，就保持R5為1

LK6_EXIT:

LCALL BEEP2 ;誤操作鍵盤發(fā)聲

AJMP LK6_ESC

LKEY_NUM:

MOV A,R0

INC R0

MOV DPTR,#KEY_VALUE

MOVC A,@A+DPTR

CJNE A,KEYS,LKEY_NUM

DEC R0

MOV A,R0

MOV DPTR,#TAB

MOVC A,@A+DPTR

MOV KEYS,A

ORL A,#30H

MOV SHOW0,A

LCALL LED_MOVE ;調(diào)用左移功能

MOV SHOW4,SHOW0

LK6_ESC:

ACALL KEY_RELEASE

LJMP LOGIN_MAIN

;=======================================END=================================================

;================================登陸系統(tǒng)========================================

SYS_LOGIN:

MOV SHOW1,#01H

MOV SHOW2,#11H

MOV SHOW3,#21H

MOV SHOW4,#31H

CLR GREEN ;綠燈亮表示開鎖成功

SYS_MAIN: ;開鎖狀態(tài)主程序

MOV P2, #0FH

MOV P3, #00H

LCALL KEY_FIRST ;調(diào)用鍵盤掃描程序

JNB KEYCARD,SYS_MAIN

LCALL KEY_MAIN ;調(diào)用鍵盤處理程序

LJMP SYSKEY_FUNCTION

;==================================登陸系統(tǒng)后各鍵功能===================================

SYSKEY_FUNCTION:

MOV A,KEYS

;================修改密碼鍵===============

SYSK1:

CJNE A,#0EDH,SYSK2

SET_PWD:

MOV R5,#05H

CLR KEY_LOCK

MOV SHOW1,#0AH

MOV SHOW2,#1AH

MOV SHOW3,#2AH

MOV SHOW4,#3AH

SETPWD_MAIN: ;修改密碼主程序

MOV P2, #0FH

MOV P3, #00H

LCALL KEY_FIRST ;調(diào)用鍵盤掃描程序

JNB KEYCARD,SETPWD_MAIN

LCALL KEY_MAIN ;調(diào)用鍵盤處理程序

LJMP SKEY_FUNCTION

;================恢復出廠設置===========

SYSK2:

CJNE A,#0EBH,SYSK3

LCALL PWD_INIT

LCALL KEY_RELEASE

LJMP SYS_MAIN

;=================退出鍵==================

SYSK3:

CJNE A,#0E7H,SYSK4

MOV SHOW1,#00H

MOV SHOW2,#10H

MOV SHOW3,#20H

MOV SHOW4,#30H

CLR KEY_LOCK

SETB GREEN ;關(guān)綠燈

LJMP MAIN ;跳回主程序

;==================無效鍵==================

SYSK4:

LCALL BEEP2

LCALL KEY_RELEASE

LJMP SYS_MAIN

;==================================END==================================================

;=================================修改密碼各鍵功能==========================================

SKEY_FUNCTION:

MOV A,KEYS

;=================無效鍵=====================

SK0:

CJNE A,#0EEH,SK1

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

SK1:

CJNE A,#0EDH,SK2

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

SK2:

CJNE A,#0EBH,SK3

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

;=================退出修改密碼================

SK3:

CJNE A,#0E7H,SK4

MOV SHOW1,#01H

MOV SHOW2,#11H

MOV SHOW3,#21H

MOV SHOW4,#31H

LCALL KEY_RELEASE

LJMP SYS_MAIN

;==================清除鍵=====================

SK4:

CJNE A,#07BH,SK5

MOV SHOW1,#0AH

MOV SHOW2,#1AH

MOV SHOW3,#2AH

MOV SHOW4,#3AH

MOV R5,#05H

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

;=================確認鍵======================

SK5:

CJNE A,#077H,SK6

LCALL KEY_RELEASE

CJNE R5,#01H,SETPWD_FAIL ;當輸入個數(shù)小于4個，則密碼修改不成功

LCALL SETPWD_SUCCESS ;成功調(diào)用SETPWD_SUCCESS

LJMP SYS_MAIN

;================0-9數(shù)字鍵=================

SK6:

MOV R0,#00H

DJNZ R5,SKEY_NUM

INC R5

LCALL BEEP2

AJMP SK6_ESC

SKEY_NUM:

MOV A,R0

INC R0

MOV DPTR,#KEY_VALUE

MOVC A,@A+DPTR

CJNE A,KEYS,SKEY_NUM

DEC R0

MOV A,R0

MOV DPTR,#TAB

MOVC A,@A+DPTR

MOV KEYS,A

ORL A,#30H

MOV SHOW0,A

LCALL LED_MOVE

MOV SHOW4,SHOW0

SK6_ESC:

ACALL KEY_RELEASE

LJMP SETPWD_MAIN

;===========================================END=============================================

;====================================修改密碼失敗====================================

SETPWD_FAIL:

LJMP SET_PWD

;====================================修改密碼成功==================================

SETPWD_SUCCESS:

ANL SHOW1,#0FH

ANL SHOW2,#0FH

ANL SHOW3,#0FH

ANL SHOW4,#0FH

MOV PWD1,SHOW1

MOV PWD2,SHOW2

MOV PWD3,SHOW3

MOV PWD4,SHOW4

MOV SHOW1,#01H

MOV SHOW2,#11H

MOV SHOW3,#21H

MOV SHOW4,#31H

LCALL LAMP_GREEN ;閃綠燈

RET

;=====================================左移功能==============================================

LED_MOVE:

CLR C

MOV A, SHOW2

SUBB A,#10H

MOV SHOW1,A

CLR C

MOV A, SHOW3

SUBB A,#10H

MOV SHOW2,A

CLR C

MOV A, SHOW4

SUBB A,#10H

MOV SHOW3,A

RET

;======================================密碼檢測========================================

PWD_COMPARE:

MOV A, SHOW1

ANL A, #0FH

CJNE A, PWD1,PWD_EXIT

MOV A, SHOW2

ANL A, #0FH

CJNE A, PWD2,PWD_EXIT

MOV A, SHOW3

ANL A, #0FH

CJNE A, PWD3,PWD_EXIT

MOV A, SHOW4

ANL A, #0FH

CJNE A, PWD4,PWD_EXIT

SETB PWD_RIGHT

AJMP PWD_ESC

PWD_EXIT:

CLR PWD_RIGHT

PWD_ESC:

RET

;======================================判斷鍵是否釋放====================================

KEY_RELEASE:

MOV P3,#00H

KEY_LOSEN:

MOV A,P2

ANL A,#0FH

LCALL LED_DISPLAY

CJNE A,#0FH,KEY_LOSEN

RET

;=======================================LED顯示================================

LED_DISPLAY:

JNB LED_ON,LED_OFF

MOV P0, SHOW1

LCALL DELAY10MS

MOV P0, SHOW2

LCALL DELAY10MS

MOV P0, SHOW3

LCALL DELAY10MS

MOV P0, SHOW4

LCALL DELAY10MS

LED_OFF:

MOV P0, #4FH

RET

;========================正常按鍵響聲===========================

BEEP1:

CLR SOND

LCALL DELAY1

SETB SOND

RET

;========================非法按鍵響聲============================

BEEP2:

CLR SOND

LCALL DELAY100MS

LCALL DELAY100MS

SETB SOND

RET

;=========================操作有誤閃紅燈=================================

LAMP_RED:

MOV R2,#06H

MOV R1,#0FFH

LAMP_LOOP:

DJNZ R1,LAMP_LOOP

CPL RED

MOV R1,#0FFH

DJNZ R2,LAMP_LOOP

SETB RED

RET

;==========================修改密碼成功閃綠燈==========================================

LAMP_GREEN:

MOV R2,#06H

MOV R1,#0FFH

LAMP_LOOP1:

DJNZ R1,LAMP_LOOP1

CPL GREEN

MOV R1,#0FFH

DJNZ R2,LAMP_LOOP1

CLR GREEN

RET

;========================10MS延時===========================

DELAY10MS:

MOV R2,#04H

LOOP3:

MOV R1,#0F9H

LOOP4:

DJNZ R1,LOOP4

DJNZ R2,LOOP3

RET

;========================100MS延時===========================

DELAY100MS:

MOV R2,#0FFH

LOOP7:

MOV R1,#0FFH

LOOP8:

DJNZ R1,LOOP8

DJNZ R2,LOOP7

RET

;=========================聲音延時===========================

DELAY1:

MOV R2,#0FFH

LOOP5:

MOV R1,#03FH

LOOP6:

DJNZ R1,LOOP6

DJNZ R2,LOOP5

RET

;==========================鍵值表===========================

KEY_VALUE: DB 0EEH,0EDH,0EBH,0E7H,0DEH,0DDH,0DBH,0D7H,0BEH,0BDH,0BBH,0B7H,07EH,07DH,07BH,077H

;==========================數(shù)字表===========================

TAB: DB 00H,00H,00H,00H,00H,01H,02H,03H,04H,05H,06H,07H,08H,09H

預備知識：

1、 匯編語言語句一般格式為_____________。

2、 什么是尋址方式？尋址方式分為：____________、_____________、______________、

3、 傳送指令的分類及其格式

4、 程序的基本結(jié)構(gòu)有___________、_____________、_____________三種。

5、 按控制條件，循環(huán)程序可分為_____________和_____________兩種形式。

6、 51系列的單片機的RAM為_____________,

7、 51系列的中斷源為_____________個，_____________個優(yōu)先級。

8、 總線分為_____________、_____________、_____________三類。

9、 什么是時鐘周期、機器周期、指令周期？三者之間有何聯(lián)系？

10、 在邏輯電路中，輸入和輸出只有兩種狀態(tài)，即_____________和_____________。通常以邏輯_____________和邏輯_____________表示電平高低

11、 常用邏輯電路有_____________、_____________、_____________、_____________、_____________、_____________。_____________。

12、 MCS-51的CPU能處理_____________位二進制數(shù)或代碼。

13、 51系列共有_____________個_____________位的定時器/計數(shù)器。

14、 I/O是什么？I/O口是什么？

15、 MCS-51單片機在物理結(jié)構(gòu)上有_____________個存儲空間。分別是_____________、_____________、_____________、_____________。

16、 程序內(nèi)存ROM尋址范圍從_____________到_____________，容量為_____________KB。

17、 74138譯碼器有_____________個輸入端：分別是_____________，

_____________個輸出端，分別是_____________。

18、 80C51單片機共有_____________條指令，這些條指令共有_____________種尋址方式。

19、 操作碼與操作數(shù)之間必須用_____________分開，操作數(shù)與操作數(shù)之間必須用逗號_____________分開。

20、 設某單片機系統(tǒng)的外接晶振頻率為6MHz，使用定時器1以方式0產(chǎn)生周期為500ms的等寬正方波連續(xù)脈沖，并由P1.0輸出。試寫出其設計程序。

21、 說明下列指令中源操作數(shù)采用的尋址方式。

　MOV R5，R7

　MOV A，55H

　MOV A，＃55H

JMP @A+DPTR

22、 段數(shù)碼管從內(nèi)部接線上分_____________和_____________兩種

23、 機器語言指令由_______和_______兩部分組成.

24、 八段碼顯示器的結(jié)構(gòu)及其工作原理。

25、 如何用八段碼顯示器顯示數(shù)字“3”？

流程卡：（2個課時）

操作流程卡
課題電子密碼鎖的制作與維修
序號	操作內(nèi)容	工作時間
學生： 日期： 教師：

電路板制作：（15個課時）

1、 準備本項任務所需的材料、工具，

2、 如果不全，缺哪些？

3、 根據(jù)上一項目的制作步驟進行操作。

材料明細卡

規(guī)格	名稱	數(shù)量
74LS138	3線8線譯碼器	1片
2N3905	三極管	8個
AT89C51	單片機	1片
74LS48	BCD七段譯碼驅(qū)動器	1片
	七段共陰極數(shù)碼管	4片
1K	R1	1個
200	R2、R27	2個
5K	R3	1個
100	R4-R15、R22、R29-R32	17個
5K	R16-R21、R23-R26、R28	11個
33P	C1、C2	2個
22μ	C3	1個
	D1-D3	3個
	BUZ1	1個
齊套結(jié)構(gòu)件、緊固件、電源線及插頭
印刷電路板、
焊料、助焊劑、保險架（1副）、絕緣膠布

課題 密碼鎖的組裝與維修 參考資料提示
序號	書名	出版社
1	電工基礎	中國勞動社會保障出版社
2	電子電路基礎	中國勞動社會保障出版社
3	數(shù)字邏輯電路	中國勞動社會保障出版社
4	電子技術(shù)工藝基礎	電子工業(yè)出版社
5	電子專業(yè)技能訓練	中國勞動社會保障出版社
6	電子技能與實訓	電子工業(yè)出版社
7	MCS-51單片機原理及應用	天津大學出版社
8	單片機基礎．	北京航空航天大學出版社
9	微機原理與匯編語言實用教程》	清華大學出版社

平分卡：（2個課時）

數(shù)字鐘的組裝與維修（滿分100分）

評分頁

姓名

學號

序號

項目及配分

工藝標準

扣分標準

學生自評分

教師評分

1

密碼鎖安裝45分

1. 按圖裝配,元件的位置\極性正確 2. 焊點光亮\清潔\焊料適量 3. 布線平直 4. 無漏焊\虛焊\假焊\搭焊\濺錫等現(xiàn)象 5. 焊接后元件引腳剪腳留頭長度小于1 mm 6. 導線連接正確 7. 調(diào)諧機構(gòu)轉(zhuǎn)動靈活 8. 不損傷塑料件、絕緣層和表面涂覆層

1. 元件安裝歪斜\不對稱\, 每處扣1分 2. 錯裝\漏裝, 每處扣5分 3. 焊點不亮\焊料過多過少\布線不平直, 每處扣0.5分 4. 漏焊\虛焊\假焊\搭焊\濺錫, 每處扣3分 5. 剪腳留頭長度大于1 mm, 每處扣0.5分 6. 導線連接錯誤， 7. 損傷塑料件、絕緣層和表面涂覆層，每處扣5分 8. 其它不符合工藝要求， 每處扣1分

2

密碼鎖的調(diào)試40分

1.正確測量主要技術(shù)指標 2．能夠解決調(diào)試中出現(xiàn)的簡單問題. 3.正確使用儀器儀表

1.測量步驟錯誤,每次扣3分 2.測量結(jié)果錯誤, 每次扣2分。誤差大, 每次扣1分 3. 儀器儀表使用錯誤,每次扣3分

3

排除故障15分

故障判斷5分

1. 能夠正確觀察故障現(xiàn)象 2. 能夠正確分析故障原因，判斷故障范圍

1. 現(xiàn)象觀察錯誤，每次扣2分 2. 故障原因分析錯誤，每次扣3分 3. 故障范圍判斷過大或過小，每次扣1分

故障檢修10分

1． 檢修思路清晰，方法運用得當 2． 檢修結(jié)果正確

a) 檢修思路不清，扣5分 b) 檢修方法不當，每次扣3分 c) 檢修結(jié)果錯誤，扣10分

4

安全文明操作

3. 安全用電,不人為損壞元器件\加工件和設備等 4. 保持操作環(huán)境整潔,秩序井然,操作習慣良好

4. 發(fā)生安全事故,扣總分20分 5. 違反文明操作規(guī)程,視情況扣總分5---20分

5

合計

工作小結(jié)：（1個課時）

工作任務小結(jié)表

日期：

1：你所在的小組從接受任務到完成共用了多少時間？

2：你認為此密碼鎖的制作可以在哪些方面進行改進？

3：對你造成最大困難的是哪些工作？

4：你通過此密碼鎖的制作在哪些方面得到了提高？

5：你認為在今后的教學中是否還應按照這種教學方法來安排？